About "individually-varying times of ... PreviousNext
Mplus Discussion > Growth Modeling of Longitudinal Data >
Message/Author
 Shige Song posted on Tuesday, October 26, 2004 - 10:56 am
Dear Linda and Bengt,

I have a question of the concept of the "individually-varying times of observation". Say, I have three panels of the same group of people with two years between each panel. The respondents are of different age groups (from age 1 to age 10), and they were interviewed at different time points (for example, some were interviewed in July and some were interviewed in August).

The simplest model will be to ignore the fact that these people are of different age group and do this:

...
Model: i s | y11@0 y12@1 y13@2;
...

However, I want to make this model more realistic and take into consideration of the fact that people are from different age groups, should I use this "individually-varying times of observation" approach as discussed in pp.92-94 in the MPlus manual? I am thinking something like this:

...
Variables: ...
Tscores = age1 age2 age3;
Analysis: Type = Random;
Model: i is | y1 y2 y3 AT age1 age2 age3;
...

where age1-age3 are the newly generated variables that represent the exact age of each individual at the time of interview. Have I got this idea right?

Thanks!

Shige
 Linda K. Muthen posted on Tuesday, October 26, 2004 - 11:28 am
It sounds right.
 Shige Song posted on Tuesday, October 26, 2004 - 7:24 pm
Hi Linda,

If that's the model I think it is, then I have a problem estimating it. I got the error message:

THE ESTIMATED COVARIANCE MATRIX IS NOT POSITIVE DEFINITE AS IT SHOULD BE.
COMPUTATION COULD NOT BE COMPLETED.
PROBLEM INVOLVING VARIABLE S.

THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO AN ERROR IN THE COMPUTATION. CHANGE YOUR MODEL AND/OR STARTING VALUES.

I estimated the same model using Stata Gllamm and MlwiN (as multilevel model) and they both worked ok and gave me roughly the same estimates. Now I am trying to figure what caused the problem of "NOT POSITIVE DEFINITE" in MPlus but not in Gllamm or MlwiN. Do you have any ideas? Thanks!

Shige
 Linda K. Muthen posted on Wednesday, October 27, 2004 - 7:38 am
I would have to see the output from Glamm or MLwiN and Mplus to answer that question. I think that they hold the residual variances of the outcome equal across time and Mplus does not so therefore the models are different. Also, they may simply not print the message that the matrix is not positive definite. If you send the outputs to support@statmodel.com, I will answer the question more fully.
 Shige posted on Wednesday, October 27, 2004 - 9:45 am
Hi Linda,

It turns out that I have not set up the data correctly. After I re-organized my data set, now MPlus gives me roughly the same results as the other two packages.

Shige
 Shige Song posted on Thursday, December 30, 2004 - 10:19 am
The model I estimated above seems to be a linear growth model in the multilevel sense (the estimates are not exactly identical to what are from GLLAMM and Mlwin, but close enough). Now, I want to estimate a quadratic growth model with individually varying time of observation, what should I do? I have been searching the web for quite a while, but could not find any examples. I tried:


Analysis:
Type = random missing;
Model: i s1 | height89 height91 height93 at age89 age91 age93;
i s2 | height89 height91 height93 at age89_2 age91_2 age93_2;


Where age89_2=age^2, age91_2=age91^2, age93_2=age93^2. But I got the error message:


*** ERROR in Model command
Random slopes previously defined:
I S2


Why is this?

Thanks!

Shige
 Linda K. Muthen posted on Thursday, December 30, 2004 - 1:47 pm
See the AT option of the MODEL command. For a quadratic model, you need three growth factor names.
 Shige Song posted on Friday, December 31, 2004 - 7:55 am
Hi Linda,

Thanks, that's very helpful!

Can you also tell me where I can find some references on estimating piecewise growth model with individually varying time of observations using Mplus? Examples from the manual and course reader deal with these two issues (that is, piecewise growth model and growth model with individually varying time of observations) separately. I've been trying to put them together to do a piecewise growth model with individually varying time of observations without luck. Thanks!

Happy new year!

Best,
Shige
 bmuthen posted on Friday, December 31, 2004 - 8:00 am
Best wishes for the new year in Beijing, Shige.

I am not aware of references that cover this combination. Perhaps you can contact Paras Mehta at the U of Houston to see if he knows. But I'd be happy to take a look at your example to see if I can figure it out.
 Shige Song posted on Friday, December 31, 2004 - 10:26 am
Hi Bengt,

Thanks! I will try to contact Paras Mehta and see if he has done something on this topic. Meanwhile, I have estimated a piecewise growth model using Stata+Gllamm and try to estimate an equavalent model using Mplus. I plan to spend some more time on this and try different possibilities before sending you anything.

I have a more general question at this moment though. Without individually varying time points, Mplus is extremely felxible in handling nonlinear growth pattern (which as I understand has something to do with the SEM approach toward growth problem). One can estimate many type of models including linear, quadratic, piecewise linear, logistic, ...etc. However, when there are individually varying time points involved, the choices are limitted: intercept, linear, quadratic, and cubic (Pp. 458). My question is: if none of the above four models produces good enough fit to the data (which is indeed true in my case), what should I do next?

Piecewise linear model is one possibility, and there may be others. But again the presence of individually varying time points makes things much more complicated...

Thank you very much, and happy new year!

Best,
Shige
 bmuthen posted on Friday, December 31, 2004 - 10:54 am
I think Mplus Discussion has had the issue of individually-varying times of observations (using the Mplus "AT" option) together with piecewise before and we presented a solution - but I can't remember exactly what it was, but you can certainly do piecewise and AT using 2 separate sets of intercepts and slopes for the two pieces and then hold parameters equal for growth factors assumed to be the same. For instance if you have the intercepts i1 and i2 for the 2 pieces, you can have the equality constraints:

[i1 i2] (1);
i1 i2 (2);

etc for covariances and regression slopes.

On the other matter of flexibility, it sounds like you want to have the combination of the SEM estimation of time scores (treating them as parameters that do not vary across people) and the multilevel practice of entering time scores as data rather than parameters. This combination would in principle seem possible, at least if individuals at the same approximate timing could be said to have the same time score parameter to be estimated - I have not seen this idea carried out, but if it is identified I would think it can be done in Mplus.
 Linda K. Muthen posted on Friday, December 31, 2004 - 4:48 pm
You could also use ON instead of AT to deal with this issue:

i by y1-y3@1;
s1 | y1 on t1;
s1 | y2 on t2;
s1 | y3 on t3;
s2 | y1 on t12;
s2 | y2 on t22;
s2 | y3 on t32;
y1 with y2-y3@0;
y2 with y3@0;
 Shige Song posted on Saturday, January 01, 2005 - 8:08 pm
Hi Linda & Bengt,

Thanks for the help!

I tried Linda's approach. I begin with a simple example to check if Linda's approach reproduces exactly what we know the correct output. Here is the "correct" code:
...
Model: i s1 | h89 h91 h93 at a89 a91 a93;
...
and here is Linda's approach:
...
Model: i by h89 h91 h93@1;
s1 | h89 on a89;
s1 | h91 on a91;
s1 | h93 on a93;
h89 with h91-h93@0;
h91 with h93@0;
...

But they did not procude exactly the same results. For example, the "correct" model has DF of 8 and Linda's approach has DF of 10; parameter estimates are not identical either (close though).

I also tried Bengt's suggestion as this:
...
Model: i1 s1 | h89 h91 h93 at a89 a91 a93;
i2 s2 | h89 h91 h93 at a89_2 a91_2 a93_2;
i1 i2 (1);
[i1 i2] (2);
...
where a89_2 a91_2 a93_2 are squared terms of a89 a91 a93 (generated in Stata). But I got error message:
THE ESTIMATED COVARIANCE MATRIX IS NOT POSITIVE DEFINITE AS IT SHOULD BE.
COMPUTATION COULD NOT BE COMPLETED.
PROBLEM INVOLVING VARIABLE S2.


THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO AN ERROR IN THE
COMPUTATION. CHANGE YOUR MODEL AND/OR STARTING VALUES.

The post Bengt mentioned is this (I think):
http://www.statmodel.com/discussion/messages/14/478.html?1096047165
but there is only a question without answer.

By the way, Mplus is an amzaing software, the more I learn, the more I want to learn. :)

Happy new year!

Shige
 Linda K. Muthen posted on Sunday, January 02, 2005 - 9:45 am
One mistake in my suggestion is that you don't have all of the factor loadings for i fixed at one. You should change

i by h89 h91 h93@1;

to

i by h89@1 h91@1 h93@1;

or

i by h89-h93@1;

I would then suggest asking for TECH1. This will show you the free parameters in Mplus for your model. Then compare this to the free parameters in whatever you are comparing to. If you make the model parameters the same, you will most likely get the same results.
 bmuthen posted on Sunday, January 02, 2005 - 9:56 am
Linda will answer your 3 specific questions, but let me raise a more general issue.

In answering your specific questions, I lost track of what your questions originated from. Looking back at your earlier message, it seems like you have people measured 3 times but you have different age groups in your data. I wonder how many distinct ages are represented in your data and in relation to this, have you considered the following two approaches instead of using "AT"? (1) a multiple-cohort (multi-group) analysis of the age groups. (2) stringing out your outcomes as one per age, where each age group has missing data at some ages. I would be interested in seeing a table of your data structure layed out like the NLSY data on page 98 of the Mplus growth modeling handout ("Day 2") that you have.

Note also that with only 3 time points per person, general piecewise modeling can't be supported - you should have at least 3 time points for each of the two pieces since each piece is its own growth model. Otherwise, it seems you have to work with a piecewise model that has strong parameter restrictions, e.g having a fixed-effect second-piece slope and all other parameters the same for the two pieces. But this is not a good way to handle fitting of 3 time points, I think. I would as a first step consider approach (1) above.
 bmuthen posted on Sunday, January 02, 2005 - 9:59 am
Regarding the specifics in trying my suggestion, note also that the message

THE ESTIMATED COVARIANCE MATRIX IS NOT POSITIVE DEFINITE AS IT SHOULD BE.
COMPUTATION COULD NOT BE COMPLETED.
PROBLEM INVOLVING VARIABLE S2.

indicates that s2 may have a close to zero variance - check the output. If so, make s2 a fixed effect by fixing its variance to zero,

s2@0;
 Jennie Jester posted on Friday, May 20, 2005 - 11:01 am
Can I use individually-varying times of observation in a growth mixture model with categorical indicators?
 bmuthen posted on Friday, May 20, 2005 - 11:03 am
Yes.
 Jennie Jester posted on Friday, May 20, 2005 - 11:57 am
So, can I do something like this?
PHYS2 BY doe8at2 doe16at2 doe22at2 doe23at2 doe24at2 doe25at2;
PHYS3 BY doe8at3 doe16at3 doe22at3 doe23at3 doe24at3 doe25at3;
PHYS4 BY doe8at4 doe16at4 doe22at4 doe23at4 doe24at4 doe25at4;
PHYS5 BY doe8at5 doe16at5 doe22at5 doe23at5 doe24at5 doe25at5;
PHYS6 BY doe8at6 doe16at6 doe22at6 doe23at6 doe24at6 doe25at6;
i s | phys2-phys6 AT age2-age6;

Where doe are categorical indicators measured at time-varying points that are stored in the age variable?
 bmuthen posted on Saturday, May 21, 2005 - 8:23 am
Yes, Mplus can handle this. But note that you should have measurement invariance across time for this to make sense because a given measurement occasion is at different times for different people.
 Jennie Jester posted on Friday, June 17, 2005 - 12:32 pm
When I use this syntax:
USEVARIABLES ARE contsym1 contsym2 contsym3
contsym4 contsym5 aget1 aget2 aget3 aget4 aget5;
TSCORES ARE aget1 aget2 aget3 aget4 aget5 ;
ANALYSIS:
type = random missing ;
MODEL:
i s| contsym1- contsym5 AT aget1 - aget5;
where contsym1 - contsym5 are continuous variables and aget1-aget5 are the individual ages for the people in the sample - this seems to work. However, this syntax:
USEVARIABLES ARE contsym1 contsym2 contsym3
contsym4 contsym5 aget1 aget2 aget3 aget4 aget5;
TSCORES ARE aget1 aget2 aget3 aget4 aget5 ;
ANALYSIS:
type = random missing ;
MODEL:
i s | contsym1 contsym2 contsym3
contsym4 contsym5 at aget1 aget2 aget3 aget4 aget5;

OUTPUT:
sampstat;
Generates this error:

*** ERROR in Model command
The number of fixed time scores is not sufficient for model identification
in the following growth process: I S

I thought that those two syntaxes were identical and don't know what is going wrong.

I am also having trouble installing the patch to upgrade to version 3.12. I wasn't sure if I had the base + combination add-on, but if I try the others, I get an error that I have an invalid Mplus.exe in my path environment. When I try the combination, it starts to go through installing, but then says I need to have Mplus Base 3.0 +Combination installed.

Thanks for the help,

Jennie
 Linda K. Muthen posted on Saturday, June 18, 2005 - 8:24 am
Please send your message to support@statmodel.com. These questions are better answered in that way.
 Aaron Alford posted on Thursday, July 07, 2005 - 6:18 pm
Dear Dr.'s Muthen,
Is it possible to extend the growth model from example 6.12 (current user's manual; Growth model with indivually varying times of observation) into the GGMM framework using Mplus?
Thanks!
 Linda K. Muthen posted on Thursday, July 07, 2005 - 7:11 pm
Yes.
 wendy posted on Monday, July 17, 2006 - 3:13 pm
Hi,Dr. Muthen:
I would like to use NLSY data to conduct my research and do you know how to assess to NLSY dataset from UCLA web? I need a UCLA faculty sponsor to receive a guest ID. Thanks for your help
 Bengt O. Muthen posted on Monday, July 17, 2006 - 5:53 pm
I don't know. But you can buy the NLSY CD for about $20 from the originators at the Ohio State Univ.
 Stephen Tueller posted on Thursday, March 22, 2007 - 7:51 pm
Do you know of any journal or technical references that address "individually-varying times of observation" in the Mplus latent variable modeling framework?
- Thanks
 Linda K. Muthen posted on Friday, March 23, 2007 - 9:12 am
Following are two references that can be found on the website under Papers:

Muthén, B. & Asparouhov, T. (2006). Growth mixture analysis: Models with non-Gaussian random effects. Forthcoming in Fitzmaurice, G., Davidian, M., Verbeke, G. & Molenberghs, G.(eds.), Advances in Longitudinal Data Analysis. Chapman & Hall/CRC Press.

Asparouhov, T. & Muthen, B. (2006). Multilevel mixture models.
Forthcoming in Hancock, G. R., & Samuelsen, K. M. (Eds.). (2007).
Advances in latent variable mixture models. Charlotte, NC: Information
Age Publishing, Inc.
 Cindy Schaeffer posted on Tuesday, September 04, 2007 - 12:17 pm
Hi - I am running growth models on 5 time points of data. When I ran the models using fixed time points I determined that a three growth factors (i.e., the inclusion of a quadratic term) resulted in significantly better model fit.

In switching to individually-varying times of observation I found that my models run fine with only intercept and slope factor estimates but do not converge with the inclusion of the quadratic. I'm pretty sure my syntax is correct:

USEVARIABLES ARE rwDtotT0 rwDtotT2 rwDtotT4 rwDtoT10 rwDtoT16
ctimwT0 ctimwT2 ctimwT4 ctimwT10 ctimwT16; Tscores are ctimwT0 ctimwT2 ctimwT4 ctimwT10 ctimwT16;

ANALYSIS: TYPE = random missing;

MODEL:
i s q| rwDtotT0-rwDtoT16 AT ctimwT0-ctimwT16;

The error message is:
THE ESTIMATED COVARIANCE MATRIX IS NOT POSITIVE DEFINITE AS IT SHOULD BE.
COMPUTATION COULD NOT BE COMPLETED.
THE RESIDUAL CORRELATION BETWEEN S AND I IS -1.000

THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO AN ERROR IN THE
COMPUTATION. CHANGE YOUR MODEL AND/OR STARTING VALUES.

In general, what would you recommend to fix this problem?

thanks for your help!
Cindy Schaeffer
 Cindy Schaeffer posted on Tuesday, September 04, 2007 - 12:22 pm
Can I have a growth model in which I use individually-varying times of observation for the estimates of i and s, but fixed time estimates for q (the quadratic growth factor)? I have tried this using the following model command:

ANALYSIS: TYPE = random missing;

MODEL:
i s | rwDtotT0-rwDtoT16 AT ctimwT0-ctimwT16;
q | rwDtotT0@0 rwDtotT2@1 rwDtotT4@4 rwDtoT10@25 rwDtoT16@64;

but get the error:
MAXIMUM LOG-LIKELIHOOD VALUE FOR THE UNRESTRICTED (H1) MODEL IS -1590.808

THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO AN ILL-CONDITIONED
FISHER INFORMATION MATRIX. CHANGE YOUR MODEL AND/OR STARTING VALUES.

THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO A NON-POSITIVE
DEFINITE FISHER INFORMATION MATRIX. THIS MAY BE DUE TO THE STARTING VALUES
BUT MAY ALSO BE AN INDICATION OF MODEL NONIDENTIFICATION. THE CONDITION
NUMBER IS -0.363D-15.

THE STANDARD ERRORS OF THE MODEL PARAMETER ESTIMATES COULD NOT BE
COMPUTED. THIS IS OFTEN DUE TO THE STARTING VALUES BUT MAY ALSO BE
AN INDICATION OF MODEL NONIDENTIFICATION. CHANGE YOUR MODEL AND/OR
STARTING VALUES. PROBLEM INVOLVING PARAMETER 7.

thanks again,
Cindy Schaeffer
 Linda K. Muthen posted on Tuesday, September 04, 2007 - 1:26 pm
You cannot combine fixed and individually-varying times of observation. When you have these types of problems, please send your input, data, output, and license number to support@statmodel.com.
 Michelle Little posted on Thursday, October 04, 2007 - 5:48 pm
Why is it not ok to combine fixed and individually varying time scores? I have done this in the past without problems with convergence...

Thanks

Michelle Little
 Linda K. Muthen posted on Friday, October 05, 2007 - 6:12 am
Time scores cannot be both parameters and data in the same model. They can play only one of these roles. I'm not sure if this is what you mean. I would have to see exactly what you did to say more. If you would like, please send your output and license number to support@statmodel.com.
 Tim Stump posted on Friday, October 09, 2009 - 6:17 am
When specifying a model in Mplus with individually-varying times of observation, can the number of observations for each subject be different? That is, can one subject contribute 8 observations while another contributes 5 and another only contributes 2?
 Linda K. Muthen posted on Friday, October 09, 2009 - 8:59 am
Yes. This is done using missing data for the measurements that observations were not present for.
 Brondeel Ruben posted on Thursday, August 12, 2010 - 8:57 am
Dear Linda,

I would like to fit a two-level growth model with individual specific timescores. Can this be done in Mplus?
Previous analyses show that both the use of the individual timescores (if I disregard the two-level design) is important as well as the two-level design (using fixed regular timescores).
I was looking for a way to do a 3-level analysis on a long dataset, but I can't find an example in the user's guide.

Kind Regards,
Ruben.
 Linda K. Muthen posted on Thursday, August 12, 2010 - 9:33 am
Three-level analysis can be done only if one level is repeated measures in a wide format. See Example 9.12. The AT option allows for individually-varying times of observation.
 Brondeel Ruben posted on Friday, August 13, 2010 - 6:01 am
I think I managed. I didn't realize that the different analysis types (complex and random) could be combined. I only used those combinations that were used in de User's Guide.
This is the code, and it worked as expected. Do you think I makes sense?
And how to compare this model with a model with fixed time points? The fit indices are not comparable. But is there something else that could help me to make an educated guess what the best model is?

Tscores = tijd_1 - tijd_3;
cluster = hh;
analysis: type = random complex;
model: i s | qol_1 qol_2 qol_3 at tijd_1 - tijd_3 ;
i s on bel_reg EOO vrouw age werk
income conflict auton i_beide i_ex ;
 Linda K. Muthen posted on Friday, August 13, 2010 - 6:21 am
This seems correct. I would however fit the growth model before I added covariates.

See the ESTIMATOR option in the user's guide where all combinations of the TYPE option are shown.
 Helen Wilson posted on Monday, August 23, 2010 - 3:29 pm
Hi Linda,
I am testing a model with individually varying times of observation. The model below includes three points of data collection (T1, T3, T5), with ages ranging from 12-16 at time 1 14-18 at time 5 (in order to use whole numbers for age, since data was collected every 6 months, I only used three of 5 points). T1numpar-T5numpar refers to number of sexual partners at each time.

USEVARIABLES ARE T1numpar T3numpar T5numpar
T1age T3age T5age;
MISSING ARE blank;
TSCORES = T1age-T5age;

ANALYSIS:
TYPE = RANDOM;

MODEL:
i s | T1numpar T3numpar T5numpar AT T1age-T5age;
T1numpar with T3numpar T5numpar;

First, am I correct that I actually have 7 time points in this model (reflecting ages 12-18 across the time points)? And the resulting slope represents change over age rather than over time of data collection? And intercept represents the number of partners at age 12 (not time 1)?

Second, when I request plot 3, only the three data collection points are represented -- is there a way to get a plot that reflects age as the time point? Also, as a related question, is there a way to generate a plot of the mean intercept and slope?

Finally, is there a way to evaluate model fit based on the loglikelihood value, and if so, could you point me to a reference?

Thank you for your help!!

Helen
 Linda K. Muthen posted on Tuesday, August 24, 2010 - 8:16 am
1. The model is estimated over age so you have 7 time points.

2. Mplus does not plot growth curves when time scores are used. You would need to do that outside of Mplus.
 Alden Gross posted on Thursday, March 10, 2011 - 11:07 am
Dear Linda and Bengt,

I hope to estimate a sequential/piecewise growth model with data in long format (thus, TYPE = TWOLEVEL;) because time is continuous and persons are seen at irregularly spaced intervals. How can I estimate such a model with piecewise growth? I am looking for a marriage of UG Examples 6.11 and 9.2.

Am I on the right track with the following?

model:
%within%
s1 | y ON timea;
s2 | y ON timeb;
%between%
[y]; [s1]; [s2]; s1 s2 WITH y;

DEFINITIONS
timea=time if time<=5, 0 otherwise
timeb=time if time>5, 0 otherwise

Thanks much!
Alden
 Bengt O. Muthen posted on Thursday, March 10, 2011 - 6:07 pm
I haven't tried this, but it looks right. If time goes high, you may want to divide by 10.
 Alden Gross posted on Saturday, March 12, 2011 - 10:14 am
Thanks! See you in Baltimore.
 Huiping Xu posted on Tuesday, November 15, 2011 - 11:04 am
Dear Linda and Bengt,

Can we do individually varying time of observations in growth mixture models? I have subjects measured at different ages and would like to find different developmental patterns. This is what I tried for a two-class model:

VARIABLE: NAMES ARE y1-y4 t1-t4;
USEVAR = y1-y4;
TSCORES = t1-t4;
CLASSES = c(2);
MISSING = ALL (999);

ANALYSIS: TYPE = MIXTURE missing;

MODEL:
%OVERALL%
i s | y1-y4 AT t1-t4;
I-S@0;

But it produces an error message:
*** ERROR in VARIABLE command
TSCORES option is only available with TYPE = RANDOM.

Could you please point me to the right direction? Thanks a lot.

Huiping
 Huiping Xu posted on Tuesday, November 15, 2011 - 11:41 am
I figured it out. Instead of ANALYSIS: TYPE = MIXTURE missing, I have ANALYSIS: TYPE = MIXTURE RANDOM missing and it worked. Thanks.
 Sam Hyun Yoo posted on Thursday, November 17, 2011 - 6:08 pm
Dear Linda and Bengt,

With NLSY79 data, I was trying to run growth curve model and encountered an error.
I have eight cohorts for 17 waves, and time intervals are unequally spaced (1-2 years) -unbalanced design.
With TSCORE option. I was trying to use 'individually varying time score. (also considering a count outcome)

Could you let me know what the problem is?

Best,
Sam

DATA: FILE IS LCMBASELINE.dat;
VARIABLE:
MISSING = ALL (-1234);
NAMES = *** (omit);
USEVARIABLES = *** (omit) ;

TSCORES = TS79 TS82 TS83 TS84 TS85 TS86 TS88
TS90 TS92 TS94 TS96 TS98 TS00 TS02
TS04 TS06 TS08 ;
COUNT = EXP79 EXP82 EXP83 EXP84 EXP85 EXP86 EXP88
EXP90 EXP92 EXP94 EXP96 EXP98 EXP00 EXP02
EXP04 EXP06 EXP08 ;
ANALYSIS: TYPE=RANDOM;
MODEL:
I S| EXP79 EXP82 EXP83 EXP84 EXP85 EXP86 EXP88
EXP90 EXP92 EXP94 EXP96 EXP98 EXP00 EXP02
EXP04 EXP06 EXP08 AT
TS79 TS82 TS83 TS84 TS85 TS86 TS88
TS90 TS92 TS94 TS96 TS98 TS00 TS02
TS04 TS06 TS08 ;
I S ON NSIBLING HISP BLACK ;
OUTPUT: SAMPSTAT MODINDICES TECH1 TECH8 ;
Plot: type = plot3;

*** ERROR in MODEL command
Observed outcomes in a growth process must be measured on the same scale.
Problem with: I S
 Linda K. Muthen posted on Thursday, November 17, 2011 - 6:28 pm
Please send the full output and your license number to support@statmodel.com.
 Joe posted on Monday, November 26, 2012 - 10:13 am
Hello:

Is it acceptable to compare the fit indices (AIC, BIC, and ABIC) between a "regular" growth model using ML estimation with fixed time scores (e.g., 0 1 2 3 4) , and a growth model using "TYPE=RANDOM" with individually-varying time scores?

Or do the model estimations use a different covariance structure and make comparisons unacceptable?

Thanks,
Joe
 Linda K. Muthen posted on Tuesday, November 27, 2012 - 10:14 am
These models have the same set of dependent variables. You can compare them using BIC because the metric of the BIC's are the same. The models are not nested.
 Ashley Hum posted on Saturday, September 07, 2013 - 2:23 pm
Hi,
I am trying to run a growth model with individually-varying times of observation after using multiple imputation to address missing data. I have 5 years of data, the first 2 years were actually collected at the same time point (thus all time data is the same across participants), but the latter time points were collected at different time points (thus the time since baseline differs across individuals). When I run the below input, the output that comes up only shows my syntax. Could you please advise on how to correct the syntax so the model will run?

Data:
File is "imp3list.dat";
TYPE= IMPUTATION;

Variable:
Names =
ASH98M ASH99M ASH02M ASH03M ASH04M
TS98 TS99 TS02 TS03 TS04;

usevariables =
ash98m ash99m ash02m ash03m ash04m
ts98 ts99 ts02 ts03 ts04;
tscores = ts98 ts99 ts02 ts03 ts04;
Missing = all (-99);

Analysis:
type = random;
estimator = ML;

Model:
i s | ash98m ash99m ash02m ash03m ash04m AT ts98 ts99 ts02 ts03 ts04;


Thanks,
Ashley
 Linda K. Muthen posted on Saturday, September 07, 2013 - 3:21 pm
Please send your input, data, and license number to support@statmodel.com.
 Louise van Elst posted on Monday, June 01, 2015 - 8:22 am
I would like to plot my latent classes. My outcome is measured at 3 different time points over a period of 2 years. The exact time points differ between people. How can I plot this? I am using time scores and I read above that mplus does not plot growth curves when time scores are used. Is this still the case?

Thank you in advance for you answer.
 Stephen Tueller posted on Monday, June 01, 2015 - 8:40 am
I've not seen a way to do individual trajectories in Mplus with individually-varying times of observation (which is what I think Louise is asking for). If individual trajectories is what is wanted,
try the longCatEDA R package, longContPlot() if your data are continuous, longCatPlot() if your data are categorical.
 Louise van Elst posted on Monday, June 01, 2015 - 2:47 pm
Sorry, maybe my question was unclear. I don't want individual trajectories. What I mean is that each individual was measured at 3 time points, but these time points were different for everyone. T0 is the same for everyone, but for example T1 could be measured at 4, 5, 6, 7, etc. weeks. I would like to create a plot with non-individual trajectories over time (from baseline to the last week in which patients were measured)I have tried to create this, but the plot only gives me the valuess at baseline for each class and the time values on x-asis don't make sense.
 Bengt O. Muthen posted on Monday, June 01, 2015 - 7:28 pm
The TSCORES are saved into the GH5 as part of the individual data using TYPE=PLOT1. You can extract that information for each observation and plot however you want, for instance using R; see

http://www.statmodel.com/mplus-R/
 Louise van Elst posted on Wednesday, June 03, 2015 - 2:20 pm
Thank you.

I tried to download the mplus.R file (R source code), but it only opens in a webpage and when I try to save it, I can only do so in a txt file, not a .R file.
What am I doing wrong?
 Linda K. Muthen posted on Wednesday, June 03, 2015 - 4:02 pm
It sounds like your browser has saved the file as an HTML file by adding an extension to it. You should download the file as plain text.
 Louise van Elst posted on Thursday, June 04, 2015 - 4:39 am
Thanks again for your answer. I am very new to this and I get stuck at every step. I'm sorry, but I have another (probably simple) question.

It took me a while, but I think I found the full path of the GH5 file. However, when I type this: mplus.view.plots('I:\PROFILe\Fase 1\Statistiek\Mplus\test.gh5)it says it cannot open the file, because it does not exist.

The GH5 file is produced by the plot command, right? How can I find its right path?
 Linda K. Muthen posted on Friday, June 05, 2015 - 9:25 am
You may find that it is easier to specify the working directory in R than to type out the full path of the GH5 file. To change the working directory in R in Windows, go the File menu and choose the Change dir… option. On the Mac, go to the Misc menu and choose the Change Working Directory… option. In the dialog box, browse to the desired directory or create a new folder. Once you have changed the working directory, you only need to give the filename of the GH5 file.
 Nicholas Bishop posted on Thursday, March 03, 2016 - 7:06 pm
Hello,
I'm working on a LGM using individually varying time scores to define the time axis (individual age centered on sample mean age at baseline). In addition to other demographic measures, I'm regressing the estimated intercept and slope on age to account for individual variation in the outcome at initial measurement and change as age increases.

I assume I can use age as a predictor of variation in the outcome, whether time is defined by age or wave of measurement. Is this correct? Does the interpretation of age as a covariate differ when defining the time axis using age (versus time defined as year of measurement)?
Thanks.
 Bengt O. Muthen posted on Friday, March 04, 2016 - 5:57 pm
You will probably get fuller answers to this on SEMNET.
 Nicholas Bishop posted on Friday, March 04, 2016 - 6:42 pm
OK, thought I would start here. Thanks.
 Scott R. Colwell posted on Wednesday, July 06, 2016 - 6:51 am
Can T SCORES be binary? For example, I am thinking of using this for modeling change across different stages of motor development. There are three different stages say A, B, C. Each subject goes through all ending in C. So the T Scores would be 0 = not in this stage and 1 = in this stage. Subjects can't go backward only forward through the stages.

Thanks,
 Bengt O. Muthen posted on Wednesday, July 06, 2016 - 6:01 pm
TSCORES can have any value that make sense for your growth model. But recall that 0 means no growth.
 Emma Davies posted on Monday, March 13, 2017 - 7:34 am
Hello,

I'm trying to fit a single growth curve to my 50 imputed datasets. The outcome is a continuous variable, and I have 6 timepoints, at baseline (0), 6, 12, 52 and 86 weeks. However, the timepoint for each participant varied. I therefore want to use TSCORES to account for this. However when I run the model below, all imputed datasets "DID NOT RESULT IN A COMPLETED REPLICATION". Tech 9 errors for each replication differ for each dataset. Most datasets show this error:

THE LOGLIKELIHOOD DECREASED IN THE LAST EM ITERATION. CHANGE YOUR MODEL AND/OR STARTING VALUES.

THE MODEL ESTIMATION DID NOT TERMINATE NORMALLY DUE TO AN ERROR IN THE COMPUTATION. CHANGE YOUR MODEL AND/OR STARTING VALUES.

However some show this error:

THE ESTIMATED COVARIANCE MATRIX IS NOT POSITIVE DEFINITE AS IT SHOULD BE. COMPUTATION COULD NOT BE COMPLETED. THE VARIANCE OF QUAD APPROACHES 0. FIX THIS VARIANCE AND THE CORRESPONDING COVARIANCES TO 0 OR DECREASE THE MINIMUM VARIANCE.

NOTE: this script works when the model is just linear, but it does not fit the data.
ALSO:the quadratic model works when I don't include time and just fix abc0, abc6 etc, but I have to center it round 36week assessment for it to work. (abc0@-3.6 abc6@-3 etc) Can anyone help explain what these errors mean and how to fix them? Thank you!
 Emma Davies posted on Monday, March 13, 2017 - 7:34 am
Variable: names are
ID gender ageBase arm
region abc0 time0 ethni3
imd abc6 time6 abc12 time12
abc36 time36 abc52 time52 abc86
time86 mi_id;
USEVAR= abc0 abc6 abc12 abc36 abc52
abc86 time0 time6 time12
time36 time52 time86;
IDVARIABLE= ID;
TSCORES= time0 time6 time12 time36
time52 time86;

!missing=all (999);

Analysis:
Estimator is MLR;

Processors=4;

TYPE=RANDOM;


Model:
int lin quad | abc0-abc86 AT time0-time86;

int WITH lin;
int WITH quad;
quad WITH lin;
 Linda K. Muthen posted on Monday, March 13, 2017 - 9:38 am
Please send the output and your license number to support@statmodel.com.

Please limit future posts to one window.
 Matthew Constantinou posted on Thursday, July 06, 2017 - 5:46 am
Dear Bengt and Linda,

Am I right in thinking that time scores cannot be used in a long data set?

If so, can you recommend a method for accounting for individually varying measurement occasions in a two-level growth model with time at the within level and subject at the between level?

One method reported by Alden Gross above is to estimate multiple slopes using deferentially coded time variables (e.g., timeA >= a cut-off timepoint, timeB = < a cut-off timepoint), but I am looking for something more fine-grained.

Best wishes,
Matthew
 Linda K. Muthen posted on Thursday, July 06, 2017 - 6:06 am
Time scores are used in wide format. They are not used for long format.

If you have individually-varying times of observation, I would use the wide format and the AT option as shown in Example 6.12.
 Matthew Constantinou posted on Thursday, July 06, 2017 - 6:30 am
Hi Linda,

Thanks for your haste in clarifying that.

I need to use the long format as it handles missing data in a way that is suitable to my analysis (e.g., it includes all available observations). I am not aware of any way in which FIML and listwise deletion can be turned off in a wide analysis.
 Eric Thibodeau posted on Saturday, May 26, 2018 - 10:01 am
Hi, I'm trying to make sense of these posts on individually varying times of observation and piecewise models. I know recent changes in version 8 may make these easier, so perhaps I'll repost a question a few folks have had.

Let's assume I have a data set with only three time points of measurement (just one variable assessed at each wave, so three indicators). The first time point of measurement included a cross section of people ranging in age from 11-16 years of age (so multiple birth cohorts). Everyone was assessed, more or less, at the same time. Each wave of assessment spanned five years. So by the end of the study the oldest group would be around 26 and the youngest would be about 21. If I fit a basic LGM it's as if I had 15 time points (age 26- age 11). Let's say I was interested in a knot around 20 years of age. Even though I have only three times of measurement, can I (and what is the best way) to run a two piece growth model? There are a lot of options that Mplus features (cohort, multiple group multiple cohort, copattern) etc. Any recommendations? Thanks!
 Bengt O. Muthen posted on Sunday, May 27, 2018 - 6:14 pm
Usually, with 3 time points only, you can't identify all parameters of a growth model with 2 pieces. But using a multiple-group, multiple-cohort approach like UG ex 6.18, I would guess that it is possible given that the same growth process is assumed for all cohorts; you can try and see.
 Eric Thibodeau posted on Tuesday, May 29, 2018 - 10:08 am
Thank you very much Dr. Muthen,

Right, so I would run the multiple group multiple cohort model but allow the slopes to be different? I would choose a group where the age of the younger individuals during last wave of data collection was similar to the ages of the older individuals during the first wave of data collection. Implicit to the piecewise is the hypothesis that that the slope before the knot and the slope after the knot are different. I suppose I can formally test for that in the multiple group option. Also, in example 6.18 I understand how you vary the time scores by group according to age. Instead can I just use a definition variable approach fixing the slope loadings to each person's age at the given wave, but center the definition variables in such a way that across groups the intercept would be modeled at the same age (the knot)? That way the time scores are more precise (actual age, not rounded age).

The down side to multiple group option is that slopes across groups cannot be allowed to covary as one may do in a regular piecewise. Likewise, in regressions with outcomes of slope variability, one cannot 'control' for the effect of the alternative slope. And sample size is cut in half as each model is only estimated by half the sample.



Eric
 Bengt O. Muthen posted on Tuesday, May 29, 2018 - 5:32 pm
I think you are understanding this correctly. But I wonder - perhaps you can actually identify the covariance between the slopes of the 2 pieces because some subjects may have pieces of information pertaining to both (I have not thought this thru so I am not sure - again, experiment; SEs coming out is a pretty reliable indicator of identifiability).
 shaun goh posted on Thursday, June 06, 2019 - 1:41 am
Dear Bengt and Linda,

Is it possible to specify a latent basis curve with individually varying times of observation (e.g. Example 6.12, just unconditional LGC model).

I understand this is possible with a 'typical' LGC for 3 time points by allowing 1 factor loading on the slope factor to be freely estimated. However I would like to know if this is possible for 3 time points with individually varying times of observation.

Best Wishes

Shaun
 Bengt O. Muthen posted on Thursday, June 06, 2019 - 5:00 pm
Seems like the ideas of a latent basis approach and individually-varying times of observation are incompatible with each other. The former estimates time scores while the latter provided fixed time scores (although varying across subjects, they are not estimated parameters).
 Lisanne de Moor posted on Thursday, April 30, 2020 - 6:37 am
Dear Dr. Muthén,

I am trying to run a measurement invariance model for data in which the intervals between measurements differ between individuals. However, I also read in the discussion above that the TSCORES command can only be used for wide data, not long data.

Is there a possibility to still take into account differing intervals for individuals in measurement invariance?

Many thanks in advance!
 Bengt O. Muthen posted on Thursday, April 30, 2020 - 10:26 am
TSCORES is for wide, single-level modeling. For long, two-level modeling you work with a time variable that you regress the outcome on. We have example of both in the V8 UG.
Back to top
Add Your Message Here
Post:
Username: Posting Information:
This is a private posting area. Only registered users and moderators may post messages here.
Password:
Options: Enable HTML code in message
Automatically activate URLs in message
Action: